RETURN expression;

RETURN 后面跟表达式，会终止函数并将 expression 的值返回给调用者。此形式用于不返回集合的 PL/pgSQL 函数。

在返回标量类型的函数中，表达式的结果将自动转换为函数的返回类型，如赋值部分所述。但要返回复合（行）值，您必须编写一个提供完全请求列集的表达式。这可能需要使用显式转换。

如果您声明的函数带有输出参数，则只需编写 RETURN，后面不跟表达式。输出参数变量的当前值将被返回。

如果您声明的函数返回 void，则可以使用 RETURN 语句提前退出函数；但不要在 RETURN 后面写表达式。

函数的返回值不能未定义。如果控制在未遇到 RETURN 语句的情况下到达函数顶层块的末尾，将发生运行时错误。但是，此限制不适用于带有输出参数的函数和返回 void 的函数。在这些情况下，如果顶层块结束，将自动执行 RETURN 语句。

一些例子

-- functions returning a scalar type
RETURN 1 + 2;
RETURN scalar_var;

-- functions returning a composite type
RETURN composite_type_var;
RETURN (1, 2, 'three'::text);  -- must cast columns to correct types

RETURN NEXT expression;
RETURN QUERY query;
RETURN QUERY EXECUTE command-string [ USING expression [, ... ] ];

当 PL/pgSQL 函数声明为返回 SETOF sometype 时，处理方式略有不同。在这种情况下，要返回的单个项由一系列 RETURN NEXT 或 RETURN QUERY 命令指定，然后使用一个不带参数的最终 RETURN 命令来指示函数已执行完毕。RETURN NEXT 可与标量和复合数据类型一起使用；对于复合结果类型，将返回整个结果“表”。RETURN QUERY 将执行查询的结果追加到函数的返回集中。RETURN NEXT 和 RETURN QUERY 可以在单个集合返回函数中自由混合使用，在这种情况下，它们的输出将连接起来。

RETURN NEXT 和 RETURN QUERY 实际上并不会从函数返回——它们只是将零行或多行追加到函数的返回集中。然后，执行将继续 PL/pgSQL 函数中的下一个语句。随着连续的 RETURN NEXT 或 RETURN QUERY 命令的执行，结果集将被构建起来。最终的 RETURN（应不带参数）会导致控制退出函数（或者您可以让控制到达函数末尾）。

RETURN QUERY 有一个变体 RETURN QUERY EXECUTE，它指定要动态执行的查询。参数表达式可以通过 USING 插入到计算出的查询字符串中，这与普通 EXECUTE 命令中的方式相同。

如果您声明的函数带有输出参数，则只需编写 RETURN NEXT，后面不跟表达式。每次执行时，输出参数变量的当前值将被保存，以便最终作为结果集中的一行返回。请注意，您必须将函数声明为返回 SETOF record（当有多个输出参数时），或 SETOF sometype（当只有一个类型为 sometype 的输出参数时），才能创建带有输出参数的集合返回函数。

以下是一个使用 RETURN NEXT 的函数示例

CREATE TABLE foo (fooid INT, foosubid INT, fooname TEXT);
INSERT INTO foo VALUES (1, 2, 'three');
INSERT INTO foo VALUES (4, 5, 'six');

CREATE OR REPLACE FUNCTION get_all_foo() RETURNS SETOF foo AS
$BODY$
DECLARE
    r foo%rowtype;
BEGIN
    FOR r IN
        SELECT * FROM foo WHERE fooid > 0
    LOOP
        -- can do some processing here
        RETURN NEXT r; -- return current row of SELECT
    END LOOP;
    RETURN;
END;
$BODY$
LANGUAGE plpgsql;

SELECT * FROM get_all_foo();

以下是一个使用 RETURN QUERY 的函数示例

CREATE FUNCTION get_available_flightid(date) RETURNS SETOF integer AS
$BODY$
BEGIN
    RETURN QUERY SELECT flightid
                   FROM flight
                  WHERE flightdate >= $1
                    AND flightdate < ($1 + 1);

    -- Since execution is not finished, we can check whether rows were returned
    -- and raise exception if not.
    IF NOT FOUND THEN
        RAISE EXCEPTION 'No flight at %.', $1;
    END IF;

    RETURN;
 END;
$BODY$
LANGUAGE plpgsql;

-- Returns available flights or raises exception if there are no
-- available flights.
SELECT * FROM get_available_flightid(CURRENT_DATE);

IF boolean-expression THEN
    statements
END IF;

IF-THEN 语句是最简单的 IF 形式。如果条件为真，则执行 THEN 和 END IF 之间的语句。否则，将跳过它们。

示例：

IF v_user_id <> 0 THEN
    UPDATE users SET email = v_email WHERE user_id = v_user_id;
END IF;

IF boolean-expression THEN
    statements
ELSE
    statements
END IF;

IF-THEN-ELSE 语句在 IF-THEN 的基础上增加了功能，允许您指定当条件不为真时应执行的替代语句集。（请注意，这包括条件评估为 NULL 的情况。）

示例

IF parentid IS NULL OR parentid = ''
THEN
    RETURN fullname;
ELSE
    RETURN hp_true_filename(parentid) || '/' || fullname;
END IF;

IF v_count > 0 THEN
    INSERT INTO users_count (count) VALUES (v_count);
    RETURN 't';
ELSE
    RETURN 'f';
END IF;

IF boolean-expression THEN
    statements
[ ELSIF boolean-expression THEN
    statements
[ ELSIF boolean-expression THEN
    statements
    ...
]
]
[ ELSE
    statements ]
END IF;

有时会存在两个以上的选择。IF-THEN-ELSIF 提供了一种方便的方法来依次检查多个选项。IF 条件按顺序测试，直到找到第一个为真的条件。然后执行关联的语句，之后控制传递到 END IF 之后的下一个语句。（任何后续的 IF 条件将 不会 进行测试。）如果所有 IF 条件都不为真，则执行 ELSE 块（如果存在）。

以下是一个例子

IF number = 0 THEN
    result := 'zero';
ELSIF number > 0 THEN
    result := 'positive';
ELSIF number < 0 THEN
    result := 'negative';
ELSE
    -- hmm, the only other possibility is that number is null
    result := 'NULL';
END IF;

关键字 ELSIF 也可以拼写为 ELSEIF。

另一种完成相同任务的方法是嵌套 IF-THEN-ELSE 语句，如下面的示例所示

IF demo_row.sex = 'm' THEN
    pretty_sex := 'man';
ELSE
    IF demo_row.sex = 'f' THEN
        pretty_sex := 'woman';
    END IF;
END IF;

然而，这种方法需要为每个 IF 编写匹配的 END IF，因此当存在许多选项时，它比使用 ELSIF 更加麻烦。

CASE search-expression
    WHEN expression [, expression [ ... ]] THEN
      statements
  [ WHEN expression [, expression [ ... ]] THEN
      statements
    ... ]
  [ ELSE
      statements ]
END CASE;

简单形式的 CASE 基于操作数的相等性提供条件执行。search-expression 被（仅一次）计算，并依次与 WHEN 子句中的每个 expression 进行比较。如果找到匹配项，则执行相应的 statements，然后控制传递到 END CASE 之后的下一个语句。（后续的 WHEN 表达式不会被评估。）如果未找到匹配项，则执行 ELSE statements；但如果 ELSE 不存在，则会引发 CASE_NOT_FOUND 异常。

以下是一个简单的例子

CASE x
    WHEN 1, 2 THEN
        msg := 'one or two';
    ELSE
        msg := 'other value than one or two';
END CASE;

CASE
    WHEN boolean-expression THEN
      statements
  [ WHEN boolean-expression THEN
      statements
    ... ]
  [ ELSE
      statements ]
END CASE;

搜索式形式的 CASE 基于布尔表达式的真伪提供条件执行。WHEN 子句的每个 boolean-expression 按顺序评估，直到找到一个产生 true 的表达式。然后执行相应的 statements，然后控制传递到 END CASE 之后的下一个语句。（后续的 WHEN 表达式不会被评估。）如果没有找到真结果，则执行 ELSE statements；但如果 ELSE 不存在，则会引发 CASE_NOT_FOUND 异常。

以下是一个例子

CASE
    WHEN x BETWEEN 0 AND 10 THEN
        msg := 'value is between zero and ten';
    WHEN x BETWEEN 11 AND 20 THEN
        msg := 'value is between eleven and twenty';
END CASE;

这种形式的 CASE 与 IF-THEN-ELSIF 完全等价，除了规则是：到达一个省略的 ELSE 子句会引发错误，而不是什么都不做。

[ <<label>> ]
LOOP
    statements
END LOOP [ label ];

LOOP 定义一个无条件循环，该循环将无限重复，直到被 EXIT 或 RETURN 语句终止。可选的 label 可以被嵌套循环内的 EXIT 和 CONTINUE 语句使用，以指定这些语句引用哪个循环。

EXIT [ label ] [ WHEN boolean-expression ];

如果没有给出 label，则终止最内层循环，并接着执行 END LOOP 之后的语句。如果给出了 label，则它必须是当前或某个外层嵌套循环或块的标签。然后，指定的循环或块将被终止，并且控制将继续执行循环/块的相应 END 之后的语句。

如果指定了 WHEN，则仅当 boolean-expression 为真时才会发生循环退出。否则，控制将传递到 EXIT 之后的语句。

EXIT 可用于所有类型的循环；它不限于用于无条件循环。

当与 BEGIN 块一起使用时，EXIT 将控制传递到块末尾之后的下一个语句。请注意，为此目的必须使用标签；未标记的 EXIT 永远不会被视为匹配 BEGIN 块。（这是对 PostgreSQL 8.4 之前的版本的更改，当时允许未标记的 EXIT 匹配 BEGIN 块。）

示例

LOOP
    -- some computations
    IF count > 0 THEN
        EXIT;  -- exit loop
    END IF;
END LOOP;

LOOP
    -- some computations
    EXIT WHEN count > 0;  -- same result as previous example
END LOOP;

<<ablock>>
BEGIN
    -- some computations
    IF stocks > 100000 THEN
        EXIT ablock;  -- causes exit from the BEGIN block
    END IF;
    -- computations here will be skipped when stocks > 100000
END;

CONTINUE [ label ] [ WHEN boolean-expression ];

如果没有给出 label，则开始最内层循环的下一次迭代。也就是说，循环体中剩余的所有语句都将被跳过，并且控制将返回到循环控制表达式（如果存在）以确定是否需要另一次循环迭代。如果存在 label，则它指定了将继续执行的循环的标签。

如果指定了 WHEN，则仅当 boolean-expression 为真时才会开始循环的下一次迭代。否则，控制将传递到 CONTINUE 之后的语句。

CONTINUE 可用于所有类型的循环；它不限于用于无条件循环。

示例

LOOP
    -- some computations
    EXIT WHEN count > 100;
    CONTINUE WHEN count < 50;
    -- some computations for count IN [50 .. 100]
END LOOP;

[ <<label>> ]
WHILE boolean-expression LOOP
    statements
END LOOP [ label ];

WHILE 语句在 boolean-expression 评估为真时重复执行一系列语句。表达式在每次进入循环体之前进行检查。

例如

WHILE amount_owed > 0 AND gift_certificate_balance > 0 LOOP
    -- some computations here
END LOOP;

WHILE NOT done LOOP
    -- some computations here
END LOOP;

[ <<label>> ]
FOR name IN [ REVERSE ] expression .. expression [ BY expression ] LOOP
    statements
END LOOP [ label ];

此形式的 FOR 创建一个循环，该循环在整数值范围内迭代。变量 name 被自动定义为 integer 类型，并且仅在循环内部存在（在循环内部，忽略该变量名的任何现有定义）。给出范围的下限和上限的两个表达式在进入循环时被评估一次。如果未指定 BY 子句，则迭代步长为 1，否则为 BY 子句中指定的值，该值在循环进入时被评估一次。如果指定了 REVERSE，则在每次迭代后减去步长值，而不是加。

整数 FOR 循环的一些示例

FOR i IN 1..10 LOOP
    -- i will take on the values 1,2,3,4,5,6,7,8,9,10 within the loop
END LOOP;

FOR i IN REVERSE 10..1 LOOP
    -- i will take on the values 10,9,8,7,6,5,4,3,2,1 within the loop
END LOOP;

FOR i IN REVERSE 10..1 BY 2 LOOP
    -- i will take on the values 10,8,6,4,2 within the loop
END LOOP;

如果下限大于上限（在 REVERSE 的情况下小于），则根本不执行循环体。不会引发错误。

如果 label 附加到 FOR 循环，则可以使用带标签的限定名称引用整数循环变量。

异常处理程序经常需要识别发生的特定错误。PL/pgSQL 中获取当前异常信息有两种方法：特殊变量和 GET STACKED DIAGNOSTICS 命令。

在异常处理程序中，特殊变量 SQLSTATE 包含与引发的异常相对应的错误代码（有关可能错误代码的列表，请参阅 Table A.1）。特殊变量 SQLERRM 包含与异常相关的错误消息。这些变量在异常处理程序外部是未定义的。

在异常处理程序中，还可以通过使用 GET STACKED DIAGNOSTICS 命令来检索当前异常的信息，该命令的形式是

GET STACKED DIAGNOSTICS variable { = | := } item [ , ... ];

每个 item 都是一个关键字，用于标识要分配给指定 variable 的状态值（该变量应具有接收它的正确数据类型）。当前可用的状态项显示在 Table 41.2 中。

如果异常未为某个项设置值，则返回空字符串。

以下是一个例子

DECLARE
  text_var1 text;
  text_var2 text;
  text_var3 text;
BEGIN
  -- some processing which might cause an exception
  ...
EXCEPTION WHEN OTHERS THEN
  GET STACKED DIAGNOSTICS text_var1 = MESSAGE_TEXT,
                          text_var2 = PG_EXCEPTION_DETAIL,
                          text_var3 = PG_EXCEPTION_HINT;
END;