RETURN expression;

RETURN 后跟表达式将终止函数并将 表达式 的值返回给调用方。此形式用于不返回集合的 PL/pgSQL 函数。

在返回标量类型的函数中，表达式的结果将自动转换为函数的返回类型，如赋值中所述。但是要返回复合（行）值，您必须编写一个表达式，该表达式恰好提供请求的列集。这可能需要使用显式转换。

如果您使用输出参数声明了函数，只需编写 RETURN 而不带表达式。输出参数变量的当前值将被返回。

如果您声明函数返回 void，则可以使用 RETURN 语句提前退出函数；但不要在 RETURN 后面写表达式。

函数的返回值不能保持未定义。如果控制到达函数顶级块的末尾而没有遇到 RETURN 语句，则会发生运行时错误。但是，此限制不适用于具有输出参数的函数和返回 void 的函数。在这些情况下，如果顶级块完成，则会自动执行 RETURN 语句。

一些示例

-- functions returning a scalar type
RETURN 1 + 2;
RETURN scalar_var;

-- functions returning a composite type
RETURN composite_type_var;
RETURN (1, 2, 'three'::text);  -- must cast columns to correct types

RETURN NEXT expression;
RETURN QUERY query;
RETURN QUERY EXECUTE command-string [ USING expression [, ... ] ];

当 PL/pgSQL 函数声明为返回 SETOF sometype 时，后续过程略有不同。在这种情况下，要返回的各个项目由一系列 RETURN NEXT 或 RETURN QUERY 命令指定，然后使用不带参数的最终 RETURN 命令指示函数已完成执行。RETURN NEXT 可用于标量和复合数据类型；对于复合结果类型，将返回整个结果“表”。RETURN QUERY 将执行查询的结果追加到函数的结果集中。RETURN NEXT 和 RETURN QUERY 可以自由地混合在一个返回集合的函数中，在这种情况下，它们的的结果将被连接起来。

RETURN NEXT 和 RETURN QUERY 实际上并没有从函数中返回——它们只是将零个或多个行追加到函数的结果集。然后执行将继续执行 PL/pgSQL 函数中的下一条语句。随着连续执行 RETURN NEXT 或 RETURN QUERY 命令，结果集将被构建。最终的 RETURN（不应带参数）会导致控制退出函数（或者您也可以让控制到达函数的末尾）。

RETURN QUERY 具有一个变体 RETURN QUERY EXECUTE，它动态地指定要执行的查询。参数表达式可以通过 USING 插入到计算出的查询字符串中，这与 EXECUTE 命令中的方式完全相同。

如果您使用输出参数声明了函数，只需编写不带表达式的 RETURN NEXT。每次执行时，输出参数变量的当前值将被保存，以便最终作为结果的一行返回。请注意，当有多个输出参数时，您必须将函数声明为返回 SETOF record，或者当只有一个类型为 sometype 的输出参数时，声明为返回 SETOF sometype，以便创建一个具有输出参数的返回集合的函数。

这是一个使用 RETURN NEXT 的函数示例

CREATE TABLE foo (fooid INT, foosubid INT, fooname TEXT);
INSERT INTO foo VALUES (1, 2, 'three');
INSERT INTO foo VALUES (4, 5, 'six');

CREATE OR REPLACE FUNCTION get_all_foo() RETURNS SETOF foo AS
$BODY$
DECLARE
    r foo%rowtype;
BEGIN
    FOR r IN
        SELECT * FROM foo WHERE fooid > 0
    LOOP
        -- can do some processing here
        RETURN NEXT r; -- return current row of SELECT
    END LOOP;
    RETURN;
END;
$BODY$
LANGUAGE plpgsql;

SELECT * FROM get_all_foo();

这是一个使用 RETURN QUERY 的函数示例

CREATE FUNCTION get_available_flightid(date) RETURNS SETOF integer AS
$BODY$
BEGIN
    RETURN QUERY SELECT flightid
                   FROM flight
                  WHERE flightdate >= $1
                    AND flightdate < ($1 + 1);

    -- Since execution is not finished, we can check whether rows were returned
    -- and raise exception if not.
    IF NOT FOUND THEN
        RAISE EXCEPTION 'No flight at %.', $1;
    END IF;

    RETURN;
 END;
$BODY$
LANGUAGE plpgsql;

-- Returns available flights or raises exception if there are no
-- available flights.
SELECT * FROM get_available_flightid(CURRENT_DATE);

IF boolean-expression THEN
    statements
END IF;

IF-THEN 语句是最简单的 IF 形式。如果条件为真，则将执行 THEN 和 END IF 之间的语句。否则，将跳过它们。

示例

IF v_user_id <> 0 THEN
    UPDATE users SET email = v_email WHERE user_id = v_user_id;
END IF;

IF boolean-expression THEN
    statements
ELSE
    statements
END IF;

IF-THEN-ELSE 语句通过允许您指定一组备用语句来扩展 IF-THEN，这些语句应该在条件不为真的情况下执行。（请注意，这包括条件计算结果为 NULL 的情况。）

示例

IF parentid IS NULL OR parentid = ''
THEN
    RETURN fullname;
ELSE
    RETURN hp_true_filename(parentid) || '/' || fullname;
END IF;

IF v_count > 0 THEN
    INSERT INTO users_count (count) VALUES (v_count);
    RETURN 't';
ELSE
    RETURN 'f';
END IF;

IF boolean-expression THEN
    statements
[ ELSIF boolean-expression THEN
    statements
[ ELSIF boolean-expression THEN
    statements
    ...
]
]
[ ELSE
    statements ]
END IF;

有时，选择项不止两个。 IF-THEN-ELSIF 提供了一种方便的方法来依次检查多个选择项。 IF 条件会依次进行测试，直到找到第一个为真的条件。然后执行关联的语句，之后控制权传递到 END IF 之后的下一条语句。（任何后续的 IF 条件都不会被测试。）如果所有 IF 条件都不为真，则执行 ELSE 代码块（如果有）。

下面是一个示例

IF number = 0 THEN
    result := 'zero';
ELSIF number > 0 THEN
    result := 'positive';
ELSIF number < 0 THEN
    result := 'negative';
ELSE
    -- hmm, the only other possibility is that number is null
    result := 'NULL';
END IF;

关键字 ELSIF 也可以拼写为 ELSEIF。

完成相同任务的另一种方法是嵌套 IF-THEN-ELSE 语句，如下例所示

IF demo_row.sex = 'm' THEN
    pretty_sex := 'man';
ELSE
    IF demo_row.sex = 'f' THEN
        pretty_sex := 'woman';
    END IF;
END IF;

但是，这种方法需要为每个 IF 写一个匹配的 END IF，因此当有多个选择项时，它比使用 ELSIF 更加繁琐。

CASE search-expression
    WHEN expression [, expression [ ... ]] THEN
      statements
  [ WHEN expression [, expression [ ... ]] THEN
      statements
    ... ]
  [ ELSE
      statements ]
END CASE;

CASE 的简单形式根据操作数的相等性提供条件执行。 search-expression 会被评估（一次）并依次与 WHEN 子句中的每个 expression 进行比较。如果找到匹配项，则执行相应的 statements，然后控制权传递到 END CASE 之后的下一条语句。（后续的 WHEN 表达式不会被评估。）如果没有找到匹配项，则执行 ELSE statements；但如果不存在 ELSE，则会引发 CASE_NOT_FOUND 异常。

下面是一个简单的示例

CASE x
    WHEN 1, 2 THEN
        msg := 'one or two';
    ELSE
        msg := 'other value than one or two';
END CASE;

CASE
    WHEN boolean-expression THEN
      statements
  [ WHEN boolean-expression THEN
      statements
    ... ]
  [ ELSE
      statements ]
END CASE;

CASE 的搜索形式根据布尔表达式的真假提供条件执行。每个 WHEN 子句的 boolean-expression 会依次被评估，直到找到一个产生 true 的表达式。然后执行相应的 statements，然后控制权传递到 END CASE 之后的下一条语句。（后续的 WHEN 表达式不会被评估。）如果找不到真值结果，则执行 ELSE statements；但如果不存在 ELSE，则会引发 CASE_NOT_FOUND 异常。

下面是一个示例

CASE
    WHEN x BETWEEN 0 AND 10 THEN
        msg := 'value is between zero and ten';
    WHEN x BETWEEN 11 AND 20 THEN
        msg := 'value is between eleven and twenty';
END CASE;

这种形式的 CASE 与 IF-THEN-ELSIF 完全等效，除了到达省略的 ELSE 子句会导致错误而不是什么都不做这一规则。

[ <<label>> ]
LOOP
    statements
END LOOP [ label ];

LOOP 定义一个无条件循环，该循环无限重复，直到被 EXIT 或 RETURN 语句终止。可选的 label 可以被嵌套循环内的 EXIT 和 CONTINUE 语句用来指定这些语句引用的循环。

EXIT [ label ] [ WHEN boolean-expression ];

如果没有给出 label，则最内层循环将终止，并且接下来执行 END LOOP 之后的语句。如果给出了 label，则它必须是当前或某些外部嵌套循环或代码块的标签。然后，命名循环或代码块将终止，控制权将继续执行循环/代码块对应 END 之后的语句。

如果指定了 WHEN，则只有当 boolean-expression 为真时，循环才会退出。否则，控制权将传递到 EXIT 之后的语句。

EXIT 可以与所有类型的循环一起使用；它不限于与无条件循环一起使用。

当与 BEGIN 代码块一起使用时，EXIT 将控制权传递到代码块结束后的下一条语句。请注意，为此必须使用标签；无标签的 EXIT 从不被认为与 BEGIN 代码块匹配。（这是 PostgreSQL 的 8.4 之前版本的一个变化，这些版本允许无标签的 EXIT 与 BEGIN 代码块匹配。）

示例

LOOP
    -- some computations
    IF count > 0 THEN
        EXIT;  -- exit loop
    END IF;
END LOOP;

LOOP
    -- some computations
    EXIT WHEN count > 0;  -- same result as previous example
END LOOP;

<<ablock>>
BEGIN
    -- some computations
    IF stocks > 100000 THEN
        EXIT ablock;  -- causes exit from the BEGIN block
    END IF;
    -- computations here will be skipped when stocks > 100000
END;

CONTINUE [ label ] [ WHEN boolean-expression ];

如果没有给出 label，则开始最内层循环的下一轮迭代。也就是说，跳过循环体中所有剩余的语句，并将控制权返回到循环控制表达式（如果有）以确定是否需要另一轮循环迭代。如果存在 label，则它指定将继续执行其循环的标签。

如果指定了 WHEN，则只有当 boolean-expression 为真时，才会开始循环的下一轮迭代。否则，控制权将传递到 CONTINUE 之后的语句。

CONTINUE 可以与所有类型的循环一起使用；它不限于与无条件循环一起使用。

示例

LOOP
    -- some computations
    EXIT WHEN count > 100;
    CONTINUE WHEN count < 50;
    -- some computations for count IN [50 .. 100]
END LOOP;

[ <<label>> ]
WHILE boolean-expression LOOP
    statements
END LOOP [ label ];

WHILE 语句重复执行一系列语句，只要 boolean-expression 评估结果为真。该表达式在每次进入循环体之前都会被检查。

例如

WHILE amount_owed > 0 AND gift_certificate_balance > 0 LOOP
    -- some computations here
END LOOP;

WHILE NOT done LOOP
    -- some computations here
END LOOP;

[ <<label>> ]
FOR name IN [ REVERSE ] expression .. expression [ BY expression ] LOOP
    statements
END LOOP [ label ];

这种形式的 FOR 创建一个循环，该循环迭代一系列整数。变量 name 自动定义为 integer 类型，并且仅在循环内部存在（循环内部会忽略变量名称的任何现有定义）。在进入循环时，给出范围上下限的两个表达式会被评估一次。如果没有指定 BY 子句，则迭代步长为 1，否则为 BY 子句中指定的值，该值同样在循环入口处评估一次。如果指定了 REVERSE，则在每次迭代后会减去步长值，而不是加上。

整数 FOR 循环的一些示例

FOR i IN 1..10 LOOP
    -- i will take on the values 1,2,3,4,5,6,7,8,9,10 within the loop
END LOOP;

FOR i IN REVERSE 10..1 LOOP
    -- i will take on the values 10,9,8,7,6,5,4,3,2,1 within the loop
END LOOP;

FOR i IN REVERSE 10..1 BY 2 LOOP
    -- i will take on the values 10,8,6,4,2 within the loop
END LOOP;

如果下限大于上限（或在 REVERSE 情况下小于），则根本不会执行循环体。不会引发错误。

如果 label 附加到 FOR 循环，则可以使用限定名称（使用该 label）引用整数循环变量。

异常处理程序通常需要识别发生的特定错误。在PL/pgSQL中，有两种方法可以获取有关当前异常的信息：特殊变量和GET STACKED DIAGNOSTICS命令。

在异常处理程序中，特殊变量SQLSTATE包含与引发异常相对应的错误代码（有关可能的错误代码列表，请参阅表 A.1）。特殊变量SQLERRM包含与异常关联的错误消息。这些变量在异常处理程序之外未定义。

在异常处理程序中，还可以使用GET STACKED DIAGNOSTICS命令检索有关当前异常的信息，该命令具有以下形式

GET STACKED DIAGNOSTICS variable { = | := } item [ , ... ];

每个项都是一个关键字，用于标识要分配给指定变量的状态值（该变量应具有正确的类型以接收它）。当前可用的状态项显示在表 41.2中。

如果异常未为某个项设置值，则将返回空字符串。

下面是一个示例

DECLARE
  text_var1 text;
  text_var2 text;
  text_var3 text;
BEGIN
  -- some processing which might cause an exception
  ...
EXCEPTION WHEN OTHERS THEN
  GET STACKED DIAGNOSTICS text_var1 = MESSAGE_TEXT,
                          text_var2 = PG_EXCEPTION_DETAIL,
                          text_var3 = PG_EXCEPTION_HINT;
END;